Faculty of Medical and Health Sciences
Department of Pharmacology & Clinical Pharmacology, University of Auckland
Faculty of Medical and Health Sciences
Department of Pharmacology & Clinical Pharmacology, University of Auckland

Population pharmacokinetics model analysis

[Hide side menu]

Objective and introduction

Objectives

  1. To provide practical experience of performing population pharmacokinetic analysis.
  2. To learn how PREDPP PK models are specified using NM-TRAN.

Introduction

A data set is provided which was simulated using NONMEM. It consists of sparse observations (4 per subject) in 100 subjects after a single oral dose. The subject weight, age and sex are recorded.

NONMEM

Note: All files should be loaded from and saved to your Pharmacometrics Data\Population PK folder for this assignment.

  1. Use Windows Explorer to explore the My Pharmacometrics\Pharmacometrics Data\Population PK folder.
  2. Open the ka1.ctl file and look at the NM-TRAN control stream code.
  3. Start a NONMEM run using the ka1.ctl NM-TRAN control stream with:
    nmgo ka1
  4. When the run is finished the results will be shown in a table format extracted from the NONMEM output listing.
  5. Make a copy of ka1.ctl file so that you can test a lag time model.
    copy ka1.ctl ka1L.ctl
  6. Edit ka1L.ctl using a text editor (e.g. EditPlus) or notepad so that it looks like Figure 1..
    start notepad ka1L.ctl
    $PROBLEM First order absorption without lag (WFN extended format)
    $INPUT ID TIME AMT WT AGE SEX DV
    $DATA tgsparse.dat IGNORE=#
    $ESTIM METHOD=ZERO POSTHOC NOABORT
    $COV

    $SUB ADVAN2 TRANS2

    $THETA
    (0,1)     ; POP_CL L/h
    (0,10)    ; POP_V L
    (0,0.5)   ; POP_KA 1/h
    (0,0.5)   ; POP_TLAG h
         
    $OMEGA
    0.09 ; PPV_CL
    0.09 ; PPV_V
    0.09 ; PPV_KA
    0.09 ; PPV_TLAG

    $SIGMA
    0.01 ; RUV_CV
    0.25 ; RUV_SD mg/L

    $PK
         CL     = POP_CL*EXP(PPV_CL)
         V      = POP_V*EXP(PPV_V)
         KA     = POP_KA*EXP(PPV_KA)
         TLAG   = POP_TLAG*EXP(PPV_TLAG)
         ALAG1  = TLAG
         S2     = V

    $ERROR
          ;CP=F
          CP=A(2)/V
          Y=CP*EXP(RUV_CV) + RUV_SD

    $TABLE ID TIME WT AGE SEX CL V KA TLAG Y
    ONEHEADER NOPRINT FILE=ka1L.fit
     
    Figure 1. Code for ka1L.ctl.

  1. Run ka1L.ctl and examine the results.
    nmgo ka1L
  2. Make a copy of the better model control file so that you can see if sex affects clearance:
    copy ka1L.ctl ka1L_sexcl.ctl
  3. Edit ka1L_sexcl.ctl. Add a new parameter, FFEMCL, to make CL in females a fraction of that in males (Figure 2).
    $PROBLEM First order absorption without lag (WFN extended format)
    $INPUT ID TIME AMT WT AGE SEX DV
    $DATA tgsparse.dat IGNORE=#
    $ESTIM METHOD=ZERO POSTHOC NOABORT
    $COV

    $SUB ADVAN2 TRANS2

    $THETA
    (0,1)     ; POP_CL L/h
    (0,10)    ; POP_V L
    (0,0.5)   ; POP_KA 1/h
    (0,0.5)   ; POP_TLAG h
    (0,1,)    ; FFEMCL

    $OMEGA
    0.09 ; PPV_CL
    0.09 ; PPV_V
    0.09 ; PPV_KA
    0.09 ; PPV_TLAG

    $SIGMA
    0.01 ; RUV_CV
    0.25 ; RUV_SD mg/L

    $PK
         IF (SEX.EQ.0) THEN
            FSEXCL=FFEMCL
         ELSE
            FSEXCL=1 ; male or missing
         ENDIF
         CL     = FSEXCL*POP_CL*EXP(PPV_CL)
         V      = POP_V*EXP(PPV_V)
         KA     = POP_KA*EXP(PPV_KA)
         TLAG   = POP_TLAG*EXP(PPV_TLAG)
         ALAG1  = TLAG
         S2     = V

    $ERROR
          ;CP=F
          CP=A(2)/V
          Y=CP*EXP(RUV_CV) + RUV_SD

    $TABLE ID TIME WT AGE SEX CL V KA TLAG Y
    ONEHEADER NOPRINT FILE=ka1L_sexcl.fit

    Figure 2. Code for ka1L_sexcl.ctl.
  1. Run ka1L_sexcl.ctl and examine the results.
  2. You will notice that the objective function is worse than the Ka1L model. This means NONMEM is in a local minimum.
  3. Copy the final parameter estimates back to the ka1L.ctl file with the nmctl command:
    nmctl ka1L
  4. Open ka1L.ctl and copy the final parameter estimates to ka1L_sexcl.ctl then save ka1L_sexcl..ctl as ka1Lsexcl_b.ctl
  5. Run ka1L_sexcl_b.ctl and examine the resutlts.
  6. You can compare the results of all your runs so far with the commands:

    nmobj Summary of obj values.
    nmmbt Summary of one or more runs. Open the nmmbt_*.txt file with Excel.
  1. Experiment with changing the model and explore the influence of weight, age, and sex on the model parameters.

Assignment

  1. Describe the models you used to describe the fixed effects of covariates.
  2. Justify in biological terms the influence of each covariate you found to be important.
  3. List the objective function values for each model with a brief description of each model.
  4. Describe how you decide on the best model.
  5. Provide the control stream for the best model.